surface 
KTleafS
(
float     octaves=8,lambda=2;
float     scale=50,distorscale=0;
float     Ka=0.5,Kd=0.8,Ks=0.5,roughness=0.1,Kdback=0.8;
float     leafCenter=0.02,leafW=0.005,leafH=0.3;
color     cs1=color(0.36,0.5,0.35),cs2=color(0.956,0.947,0.63),cs3=color(0.70,0.698,0.49);
color     KScs=color(1,1,1)
)

{
point    Nf,V,PP;
float    i,value,freq;
float    judgeW,judge;
float    opas,opat,opa;
float    KD,KDback;
color    cs;

KD=Kd;
KDback=Kdback;

judgeW=mod(s,leafCenter);
if (judgeW>(leafCenter/2)) {
     judgeW=leafCenter-judgeW;
}

if (judgeW<leafW) {
    if (t<leafH) {
        opas=judgeW/leafW;
        opat=1-(t/leafH);
        judge=pow(opas,2)+pow(opat,2);
        if (judge<1) {
              opa=1-smoothstep(0.5,1,judge);
              Oi=color(1,1,1)*opa;
              cs=mix(cs2,cs1,opa);
        }
        else {
              Oi=0;
        }
    }
    else {
        opas=1-(judgeW/leafW);
        opat=(t-leafH)/(1-leafH);
        judge=pow(opat,2);
        if (judge<opas) {
              judge=sqrt(pow(1-pow(opat,2),2)-pow(1-opas,2));
              opa=smoothstep(0.01,1,judge);
              Oi=color(1,1,1)*opa;
              cs=mix(cs2,cs1,opa);
        }
        else {
              Oi=0;
        }
    }
}
else {
   Oi=0;
}

PP=scale*transform("object",P);
PP+=distorscale*(2*(point noise(PP))-point(1,1,1));

value=0;
freq=1;
for (i=1;i<octaves;i+=1) {
    value+=abs(2*noise(PP)-1)/freq;
    PP*=freq;
    freq*=lambda;
}

/*KD=KD*smoothstep(0,(leafW/12),judgeW);
*KDback=KDback*smoothstep(0,(leafW/12),judgeW);
*value=smoothstep(0,0.3,value);
*KD=KD*value;
*KDback=KDback*value;*/

cs=mix(cs3,cs,smoothstep(0,(leafW/12),judgeW));
cs=mix(cs3,cs,smoothstep(0,0.3,value));

Nf=faceforward(normalize(N),I);
V=normalize(-I);
Ci=Oi*cs*(Ka*ambient()+KD*diffuse(Nf)+KDback*diffuse(-Nf)+Ks*KScs*specular(Nf,V,roughness));

}